// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
/*

https://github.com/t-o-k/POV-Ray-L-system

Copyright (c) 2023 Tor Olav Kristensen, http://subcube.com

Use of this source code is governed by the GNU Lesser General Public License version 3,
which can be found in the LICENSE file.

*/
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

#version 3.7;

#include "L-system_2D.inc"
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "golds.inc"

global_settings { assumed_gamma 2.2 }


// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

// Quadratic Gosper curve from Lindenmayer Systems, Fractals, and Plants (lsfp.pdf), p. 25 Figure 2.7 d;
// Droj (28 Jul 2023)

// Finite Objectcs 31251 at Iterations = 3; Beware of using more than 3!

// Variables
#declare Rules[asc("F")] = "F";
#declare Rules[asc("X")] = "XFX-YF-YF+FX+FX-YF-YFFX+YF+FXFXYF-FX+YF+FXFX+YF-FXYF-YF-FX+FX+YFYF-";
#declare Rules[asc("Y")] = "+FXFX-YF-YF+FX+FXYF+FX-YFYF-FX-YF+FXYFYF-FX-YFFX+FX+YF-YF-FX+FX+YFY";

InsertNoChangeFunctions(Functions, "XY")

// Axiom
#declare Axiom = "-YF";

#declare Iterations = 3;
#declare StackSize = 2*Iterations;
#declare L_string = L_Transform(Axiom, Rules, Iterations);

#declare pStart = < -60, -60,  0>;
#declare InitialLength = 1.0;
#declare InitialRadius = 0.15;
#declare InitialHeading = radians(0.0);
#declare InitialTurnAngle = radians(90.0);

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

union {
    L_Draw(
        Functions,
        L_string,
        StackSize,
        pStart,
        InitialLength,
        InitialRadius,
        InitialHeading,
        InitialTurnAngle,
        true,
        true,
        false,
        ""
    )
    texture { T_Silver_5C }
    
    scale 0.5
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

background { color <0.0,0.0,0.0> }


camera {
    perspective
    location <0, 0, -100>
    sky       <0.0, 1.0, 0.0>  
    up        <0.0, 1.0, 0.0>
    right     x*image_width/image_height 
    angle        54.0
    look_at   <0, 0,  0>
}

light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-15, 50, -100>
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10