// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
/*

https://github.com/t-o-k/POV-Ray-L-system

Copyright (c) 2023 Tor Olav Kristensen, http://subcube.com

Use of this source code is governed by the GNU Lesser General Public License version 3,
which can be found in the LICENSE file.

*/
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

#version 3.7;


#include "L-system_2D.inc"
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "golds.inc"

global_settings { assumed_gamma 2.2 }


// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

// Dragons and Arrows from L-System (https://mathematikalpha.de/lindenmayer-system-l-system);
// Droj (3 Aug 2023)
// 
#declare GoldenRatio = (1 + sqrt(5))/2;

// Variables
#declare Rules[asc("F")] = "F";
#declare Rules[asc("f")] = "f";

#declare Rules[asc("x")] = "[F+++>F][++<fb|x|-f|a]";
#declare Rules[asc("y")] = "[+F][>F][+f<|y+x]";
#declare Rules[asc("a")] = "[F][++>F][++f---<f|x-y|f|a]";
#declare Rules[asc("b")] = "[-F][>F][<f--af|+b]";

InsertNoChangeFunctions(Functions, "abxy")

InsertLengthFunctions(Functions, GoldenRatio, 0) // > = 1.61803399

#declare Axiom = "af+xf+af+xf+af+xf+af+xf+af+x";

#declare Iterations = 6;
#declare StackSize = 2*Iterations;
#declare L_string = L_Transform(Axiom, Rules, Iterations);

#declare pStart = < -2, 7, 0>;
#declare InitialLength = 5.0;
#declare InitialRadius = 0.1;
#declare InitialHeading = radians(0.0);
#declare InitialTurnAngle = radians(36.0);

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

union {
    L_Draw(
        Functions,
        L_string,
        StackSize,
        pStart,
        InitialLength,
        InitialRadius,
        InitialHeading,
        InitialTurnAngle,
        true,
        true,
        false,
        "Dragons_Arrows_I6_obj.inc"
    )
    texture { T_Silver_5C }
    scale 1.0 // 4.0
    rotate 0*y
    translate <0.0, 0.0, 0.0>

}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

background { color <0.0,0.0,0.0> }


camera {
    perspective
    location <0, 0, -30> 
    sky       <0.0, 1.0, 0.0>  
    up        <0.0, 1.0, 0.0>
    right     x*image_width/image_height 
    angle        54.0
    look_at   <0, 0,  0>
}

light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-15, 50, -100>
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10