// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
/*

https://github.com/t-o-k/POV-Ray-L-system

Copyright (c) 2023 Tor Olav Kristensen, http://subcube.com

Use of this source code is governed by the GNU Lesser General Public License version 3,
which can be found in the LICENSE file.

*/
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

#version 3.7;

#include "L-system_2D.inc"
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "golds.inc"

global_settings { assumed_gamma 2.2 }


// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

// Some sort of tree from https://www.houdinikitchen.net/2019/12/21/how-to-create-l-systems/;
// Adapted by Droj (26 Sep 2023); a very crippled sort of a tree => I am not proud!
// 

// Variables
#declare Rules[asc("F")] = "F";
#declare Rules[asc("A")] = "FF[&B(<!]<!A";
#declare Rules[asc("B")] = "F[-C(<!](<!C";
#declare Rules[asc("C")] = "F[+B(<!](<!B";

InsertNoChangeFunctions(Functions, "ABC")
#declare LengthScale = 1.6; // < decreases length
#declare LengthIncrement = 0;
InsertLengthFunctions(Functions, LengthScale, LengthIncrement)
#declare RadiusScale = 1.5; // ! decreases radius
#declare RadiusIncrement = 0.0;
InsertRadiusFunctions(Functions, RadiusScale, RadiusIncrement)
#declare AngleScale = 1.20; // ( decreases angle
#declare AngleIncrement = 0.0;
InsertAngleFunctions(Functions, AngleScale, AngleIncrement)

// Axiom
#declare Axiom = "A";

#declare Iterations = 12; // 8215 objects
#declare StackSize = 2*Iterations;
#declare L_string = L_Transform(Axiom, Rules, Iterations);

#declare pStart = < 0, -27,  0>;
#declare InitialLength = 5.0;
#declare InitialRadius = 0.6;
#declare InitialHeading = radians(+90.0);
#declare InitialTurnAngle = radians(+45.0);

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

union {
    L_Draw(
        Functions,
        L_string,
        StackSize,
        pStart,
        InitialLength,
        InitialRadius,
        InitialHeading,
        InitialTurnAngle,
        true,
        true,
        false,
        ""
    )
    texture { T_Gold_5C }
    scale 1.0
    translate < 0.0, 0.0, 0.0 >
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10

background { color <0.0,0.0,0.0> }


camera {
    perspective
    location <0, 0, -100>
    sky       <0.0, 1.0, 0.0>  
    up        <0.0, 1.0, 0.0>
    right     x*image_width/image_height 
    angle        54.0
    look_at   <0, 0,  0>
}

light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-15, 50, -100>
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10